added my Recipes

meta-st/meta-st-openstlinux/recipes-st/images/st-image-core.bb

@@ -0,0 +1,26 @@
+SUMMARY = "OpenSTLinux core image."
+LICENSE = "Proprietary"
+
+include recipes-st/images/st-image.inc
+
+inherit core-image
+
+IMAGE_LINGUAS = "en-us"
+
+IMAGE_FEATURES += "\
+    package-management  \
+    ssh-server-dropbear \
+    "
+
+#
+# INSTALL addons
+#
+CORE_IMAGE_EXTRA_INSTALL += " \
+    resize-helper \
+    \
+    packagegroup-framework-core-base    \
+    packagegroup-framework-tools-base   \
+    \
+    ${@bb.utils.contains('COMBINED_FEATURES', 'optee', 'packagegroup-optee-core', '', d)}   \
+    ${@bb.utils.contains('COMBINED_FEATURES', 'optee', 'packagegroup-optee-test', '', d)}   \
+    "

meta-st/meta-st-openstlinux/recipes-st/images/st-image-resize-initrd.bb

@@ -0,0 +1,43 @@
+SUMMARY = "INITRD able to resize the mmc paritions"
+LICENSE = "MIT"
+
+IMAGE_FSTYPES = "${INITRAMFS_FSTYPES}"
+inherit core-image
+
+IMAGE_ROOTFS_EXTRA_SPACE = "0"
+
+# Reset IMAGE_LINGUAS to empty
+IMAGE_LINGUAS = ""
+
+# Disable partition image for InitRD image to avoid circular dependancy
+# If we keep enable this feature, when building the InitRD image a dependancy
+# will be added for the completion of bootfs image while we're just expecting
+# to add the InitRD inside bootfs...
+ENABLE_PARTITIONS_IMAGE = "0"
+
+# Disable flashlayout generation for this particular image as this is supposed
+# to be done only for complete image (bootloader binaries, bootfs, rootfs...))
+ENABLE_FLASHLAYOUT_CONFIG = "0"
+
+# Disable image license summary generation for this particular image as this is
+# supposed to be done only for complete image
+ENABLE_IMAGE_LICENSE_SUMMARY = "0"
+ENABLE_IMAGE_CVE_SUMMARY = "0"
+
+# Disable generation of multi volume ubifs  for this particular image as this is
+# supposed to be done only for complete image
+ENABLE_MULTIVOLUME_UBI = "0"
+
+PACKAGE_INSTALL = " \
+    busybox \
+    e2fsprogs \
+    e2fsprogs-e2fsck \
+    e2fsprogs-resize2fs \
+    e2fsprogs-tune2fs \
+    e2fsprogs-mke2fs \
+    initramfs-module-rootfs \
+    initramfs-module-udev \
+    initrd-boot \
+    "
+
+NO_RECOMMENDATIONS = "1"

meta-st/meta-st-openstlinux/recipes-st/images/st-image-weston.bb

@@ -0,0 +1,46 @@
+SUMMARY = "OpenSTLinux weston image with basic Wayland support (if enable in distro)."
+LICENSE = "Proprietary"
+
+include recipes-st/images/st-image.inc
+
+inherit core-image features_check
+
+# let's make sure we have a good image...
+REQUIRED_DISTRO_FEATURES = "wayland"
+
+IMAGE_LINGUAS = "en-us"
+
+IMAGE_FEATURES += "\
+    splash              \
+    package-management  \
+    ssh-server-dropbear \
+    hwcodecs            \
+    tools-profile       \
+    eclipse-debug       \
+    "
+
+#
+# INSTALL addons
+#
+CORE_IMAGE_EXTRA_INSTALL += " \
+    resize-helper \
+    \
+    packagegroup-framework-core-base    \
+    packagegroup-framework-tools-base   \
+    \
+    packagegroup-framework-core         \
+    packagegroup-framework-tools        \
+    \
+    packagegroup-framework-core-extra   \
+    \
+    ${@bb.utils.contains('COMBINED_FEATURES', 'optee', 'packagegroup-optee-core', '', d)} \
+    ${@bb.utils.contains('COMBINED_FEATURES', 'optee', 'packagegroup-optee-test', '', d)} \
+    \
+    ${@bb.utils.contains('COMBINED_FEATURES', 'tpm2', 'packagegroup-security-tpm2', '', d)} \
+    \
+    packagegroup-st-demo \
+    "
+
+# NOTE:
+#   packagegroup-st-demo are installed on rootfs to populate the package
+#   database.

meta-st/meta-st-openstlinux/recipes-st/images/st-image.inc

@@ -0,0 +1,50 @@
+LICENSE = "Proprietary"
+LIC_FILES_CHKSUM = "file://${EULA_FILE_ST};md5=${EULA_FILE_ST_MD5SUM}"
+LIC_FILES_CHKSUM[vardepsexclude] += "EULA_FILE_ST"
+
+inherit st-image-license-summary
+inherit st-sdk-license-summary
+inherit st-image-cve-summary
+
+
+EULA_FILE_ST ?= "${OPENSTLINUX_BASE}/files/licenses/ST-Proprietary"
+EULA_FILE_ST_MD5SUM ?= "7cb1e55a9556c7dd1a3cae09db9cc85f"
+
+image_copy_image_license() {
+    if [ -f ${EULA_FILE_ST} ]; then
+        cp ${EULA_FILE_ST} ${IMGDEPLOYDIR}/${IMAGE_NAME}.license
+        cd ${IMGDEPLOYDIR}; ln -sf ${IMAGE_NAME}.license ${IMAGE_LINK_NAME}.license
+    else
+        bbwarn "Missing 'EULA_FILE_ST' var : no image license copied..."
+    fi
+}
+IMAGE_POSTPROCESS_COMMAND:prepend = "image_copy_image_license;"
+
+sdk_copy_image_license() {
+    mkdir -p ${SDKDEPLOYDIR}
+    if [ -f ${EULA_FILE_ST} ]; then
+        cp ${EULA_FILE_ST} ${SDKDEPLOYDIR}/${TOOLCHAIN_OUTPUTNAME}.license
+    else
+        bbwarn "Missing 'EULA_FILE_ST' var : no image license copied..."
+    fi
+}
+SDK_POSTPROCESS_COMMAND:prepend = "sdk_copy_image_license;"
+
+LSB_RELASE_TIMESTAMP = "${DATE}-${TIME}"
+LSB_RELASE_TIMESTAMP[vardepsexclude] += "DATE"
+LSB_RELASE_TIMESTAMP[vardepsexclude] += "TIME"
+
+update_lsbreleasedate() {
+    if [ -f ${IMAGE_ROOTFS}${sysconfdir}/lsb-release ]; then
+        sed -i 's/^DISTRIB_RELEASE=\(.*\)-snapshot-.*$/DISTRIB_RELEASE=\1-snapshot-'"${LSB_RELASE_TIMESTAMP}"'/' ${IMAGE_ROOTFS}${sysconfdir}/lsb-release
+        sed -i 's/^DISTRIB_DESCRIPTION=\(.*\)-snapshot-.*\"/DISTRIB_DESCRIPTION=\1-snapshot-'"${LSB_RELASE_TIMESTAMP}"'\"/' ${IMAGE_ROOTFS}${sysconfdir}/lsb-release
+    fi
+}
+ROOTFS_POSTPROCESS_COMMAND:append = "update_lsbreleasedate;"
+
+zap_empty_weston_password () {
+    if [ -e ${IMAGE_ROOTFS}/etc/shadow ]; then
+        sed -i 's%^weston:!:%weston::%' ${IMAGE_ROOTFS}/etc/shadow
+    fi
+}
+ROOTFS_POSTPROCESS_COMMAND:append = "zap_empty_weston_password;"