added my Recipes

meta-openembedded/meta-xfce/recipes-art/cursor-themes/openzone_1.2.3.bb

@@ -0,0 +1,33 @@
+SUMMARY = "X11 Mouse Theme"
+HOMEPAGE = "http://xfce-look.org/content/show.php/OpenZone?content=111343"
+SECTION = "x11/wm"
+LICENSE = "MIT"
+LIC_FILES_CHKSUM = "file://COPYING;md5=a2f562fb8fb1e138b810d69521c4bcd7"
+
+inherit allarch gtk-icon-cache
+
+SRC_URI = "http://xfce-look.org/CONTENT/content-files/111343-OpenZone-${PV}.tar.xz"
+SRC_URI[md5sum] = "4dae968cbd525072664ef7a4fc7c4154"
+SRC_URI[sha256sum] = "dc20f97a49e1ff1becf7853ef5f137ed30a4c27490540e755021d78d339efd92"
+
+S = "${WORKDIR}/OpenZone"
+
+do_compile() {
+}
+
+do_install() {
+    install -d ${D}${datadir}/icons
+    for theme in `find -name '*.tar.xz'`; do
+        tar -Jxf ${theme} -C ${D}${datadir}/icons
+    done
+}
+
+python populate_packages:prepend () {
+    icondir = bb.data.expand('${datadir}/icons', d)
+    do_split_packages(d, icondir, '^(.*)', '%s', 'Open Zone cursors %s', allow_dirs=True)
+}
+
+FILES:${PN} += "${datadir}/icons"
+
+PACKAGES_DYNAMIC += "^openzone-.*"
+ALLOW_EMPTY:${PN} = "1"

meta-openembedded/meta-xfce/recipes-art/rodent-icon-theme/rodent-icon-theme_5.0.bb

@@ -0,0 +1,16 @@
+SUMMARY = "Rodent-icon-theme (was xfce4-icon-theme) is a svg icon theme"
+LICENSE = "GPL-2.0-only"
+LIC_FILES_CHKSUM = "file://COPYING;md5=8ca43cbc842c2336e835926c2166c28b"
+
+inherit allarch autotools gtk-icon-cache
+
+SRC_URI = "http://sourceforge.net/projects/xffm/files/${BPN}/${BPN}-${PV}.tar.gz"
+SRC_URI[md5sum] = "4b097d344a160d6497c6498985c8df15"
+SRC_URI[sha256sum] = "6ed00d16faa1f55b3bb7b13862de1d7f5cfd978b93e42487ded21595d0dbe208"
+
+FILES:${PN} += "${datadir}/icons"
+
+RREPLACES:${PN} += "xfce4-icon-theme"
+RPROVIDES:${PN} += "xfce4-icon-theme"
+RCONFLICTS:${PN} += "xfce4-icon-theme"
+

meta-openembedded/meta-xfce/recipes-art/xfce-dusk-gtk3/xfce-dusk-gtk3_1.3.bb

@@ -0,0 +1,19 @@
+SUMMARY = "Modified version of the xfce-dusk theme to support also gtk 3.x too"
+LICENSE = "GPL-3.0-only"
+LIC_FILES_CHKSUM = "file://LICENSE;md5=8f0e2cd40e05189ec81232da84bd6e1a"
+
+inherit allarch
+
+SRC_URI = "http://sources.openembedded.org/141404-xfce_dusk_gtk3-1_3.tar.gz;subdir=${BPN}-${PV}"
+SRC_URI[md5sum] = "b3ad37ad8173b14ec090e60a80e65d8f"
+SRC_URI[sha256sum] = "bfa8a88607d1a1da5bd0b9e4e075767c54400a3c5a0fae88b619ed71532f30b4"
+
+do_configure() {
+}
+
+do_install() {
+    install -d ${D}${datadir}/themes
+    cp -r Xfce-dusk-gtk3 ${D}${datadir}/themes/Xfce-dusk-gtk3
+}
+
+FILES:${PN} = "${datadir}/themes"

meta-openembedded/meta-xfce/recipes-art/xfwm4-themes/xfwm4-themes_4.10.0.bb

@@ -0,0 +1,19 @@
+SUMMARY = "Additional (old) themes for Xfwm4"
+SECTION = "x11/wm"
+LICENSE = "GPL-3.0-only"
+LIC_FILES_CHKSUM = "file://COPYING;md5=d32239bcb673463ab874e80d47fae504"
+
+inherit xfce
+
+SRC_URI = "http://archive.xfce.org/src/art/${BPN}/${@'${PV}'[0:4]}/${BP}.tar.bz2"
+SRC_URI[md5sum] = "eaa58362053a3549c8be0b32efd3c54f"
+SRC_URI[sha256sum] = "3214d5f00e9703b5e8c9e7c3287d606dedec7285ceb4d5db332e93ada66fd575"
+
+# using xfwm4-theme as in xfwm4 might cause warnings of packages supplied by
+# multiple providers. So we use xfwm4-old-theme here.
+python populate_packages:prepend () {
+    themedir = d.expand('${datadir}/themes')
+    do_split_packages(d, themedir, '^(.*)', 'xfwm4-old-theme-%s', 'XFWM4 theme %s', allow_dirs=True)
+}
+
+PACKAGES_DYNAMIC += "^xfwm4-old-theme-.*"