added my Recipes

meta-openembedded/meta-oe/recipes-support/dfu-util/dfu-util-native_0.11.bb

@@ -0,0 +1,24 @@
+require dfu-util_${PV}.bb
+
+inherit deploy native
+
+DEPENDS = "libusb1-native"
+
+PACKAGECONFIG ??= ""
+
+PACKAGECONFIG[static] = "CFLAGS='${CFLAGS} -pthread -static',,"
+
+do_deploy() {
+    install -m 0755 src/dfu-util ${DEPLOYDIR}/dfu-util-${PV}
+    rm -f ${DEPLOYDIR}/dfu-util
+    ln -sf ./dfu-util-${PV} ${DEPLOYDIR}/dfu-util
+}
+
+addtask deploy before do_package after do_install
+
+# cleandirs should possibly be in deploy.bbclass but we need it
+do_deploy[cleandirs] = "${DEPLOYDIR}"
+# clear stamp-extra-info since MACHINE_ARCH is normally put there by
+# deploy.bbclass
+do_deploy[stamp-extra-info] = ""
+

meta-openembedded/meta-oe/recipes-support/dfu-util/dfu-util_0.11.bb

@@ -0,0 +1,12 @@
+DESCRIPTION = "USB Device Firmware Upgrade utility"
+AUTHOR = "Harald Welte <laforge@openmoko.org>"
+HOMEPAGE = "http://dfu-util.sourceforge.net"
+SECTION = "devel"
+LICENSE = "GPL-2.0-only"
+LIC_FILES_CHKSUM = "file://COPYING;md5=94d55d512a9ba36caa9b7df079bae19f"
+DEPENDS = "libusb1"
+
+SRC_URI = "http://dfu-util.sourceforge.net/releases/${BP}.tar.gz"
+SRC_URI[sha256sum] = "b4b53ba21a82ef7e3d4c47df2952adf5fa494f499b6b0b57c58c5d04ae8ff19e"
+
+inherit autotools pkgconfig