added my Recipes

meta-openembedded/meta-oe/recipes-graphics/tesseract/tesseract-lang_4.1.0.bb

@@ -0,0 +1,26 @@
+SUMMARY = "tesseract-ocr language files"
+
+LICENSE = "Apache-2.0"
+LIC_FILES_CHKSUM = "file://LICENSE;md5=3b83ef96387f14655fc854ddc3c6bd57"
+
+SRCREV = "4767ea922bcc460e70b87b1d303ebdfed0897da8"
+SRC_URI = "git://github.com/tesseract-ocr/tessdata.git;branch=main;protocol=https"
+
+S = "${WORKDIR}/git"
+
+inherit allarch
+
+do_install() {
+    install -d ${D}${datadir}/tessdata
+    cp -R --no-dereference --preserve=mode,links -v ${S}/*.traineddata ${D}${datadir}/tessdata
+}
+
+python populate_packages:prepend () {
+    tessdata_dir= d.expand('${datadir}/tessdata')
+    pkgs = do_split_packages(d, tessdata_dir, r'^([a-z_]*)\.*', '${BPN}-%s', 'tesseract-ocr language files for %s', extra_depends='')
+    pn = d.getVar('PN')
+    d.appendVar('RDEPENDS:' + pn, ' '+' '.join(pkgs))
+}
+
+PACKAGES_DYNAMIC += "^${BPN}-.*"
+ALLOW_EMPTY:${PN} = "1"

meta-openembedded/meta-oe/recipes-graphics/tesseract/tesseract/0001-Fix-build-with-gcc-13-by-including-cstdint.patch

@@ -0,0 +1,32 @@
+From 2025b53de6b3d97285d7c5f80497493007c586c3 Mon Sep 17 00:00:00 2001
+From: Khem Raj <raj.khem@gmail.com>
+Date: Mon, 30 Jan 2023 11:27:07 -0800
+Subject: [PATCH] Fix build with gcc 13 by including <cstdint>
+
+gcc 13 moved some includes around and as a result <cstdint> is
+no longer transitively included [1]. Explicitly include it for
+int32_t.
+
+[1] https://gcc.gnu.org/gcc-13/porting_to.html#header-dep-changes
+
+Upstream-Status: Submitted [https://github.com/tesseract-ocr/tesseract/pull/4009]
+Signed-off-by: Khem Raj <raj.khem@gmail.com>
+---
+ src/ccutil/params.h | 1 +
+ 1 file changed, 1 insertion(+)
+
+diff --git a/src/ccutil/params.h b/src/ccutil/params.h
+index f514d870..0f3f8743 100644
+--- a/src/ccutil/params.h
++++ b/src/ccutil/params.h
+@@ -21,6 +21,7 @@
+ 
+ #include <tesseract/export.h> // for TESS_API
+ 
++#include <cstdint>
+ #include <cstdio>
+ #include <cstring>
+ #include <string>
+-- 
+2.39.1
+

meta-openembedded/meta-oe/recipes-graphics/tesseract/tesseract_5.3.0.bb

@@ -0,0 +1,22 @@
+SUMMARY = "A commercial quality OCR engine "
+HOMEPAGE = "https://github.com/tesseract-ocr/tesseract"
+BUGTRACKER = "https://github.com/tesseract-ocr/tesseract/issues"
+
+LICENSE = "Apache-2.0"
+LIC_FILES_CHKSUM = "file://LICENSE;md5=3b83ef96387f14655fc854ddc3c6bd57"
+
+SRCREV = "080da83cc51c4ef8b324a7e03146fe0bd7e0944b"
+SRC_URI = "git://github.com/${BPN}-ocr/${BPN}.git;branch=main;protocol=https \
+           file://0001-Fix-build-with-gcc-13-by-including-cstdint.patch"
+
+S = "${WORKDIR}/git"
+
+DEPENDS = "leptonica"
+
+EXTRA_OECONF += "LIBLEPT_HEADERSDIR=${STAGING_INCDIR}/leptonica"
+
+inherit autotools pkgconfig
+
+FILES:${PN} += "${datadir}/tessdata"
+
+RRECOMMENDS:${PN} += "tesseract-lang-eng"